|
PureBytes Links
Trading Reference Links
|
Zoran,
Here is something for radarscreen that might be close to what you asked for. The
"volume_btwn_bid_ask" is left to be allocated based on your own discretion. The
"<=" and "<=" statements can be further broken down, but this should illustrate
the idea.
{***************************************
On Balance Tick Volume
Indicator for RadarScreen.
Description:
1. Totals the volume for
ticks equal to and greater than the Ask.
2. Totals the volume for
ticks equal to and less than the Bid.
3. Totals the volume for ticks
between the Bid and the Ask.
4. Subtracts #2 from #1 to calculate
the On Balance Tick Volume.
Written by David Davidson.
c 2001. All rights reserved.
Note: The Input "blockamt" is used to
ignore ticks with inaccurate volume. The "blockamt"
can be totaled and plotted in a separate indicator.
****************************************}
Inputs: ask_volume_alert(100000000), bid_volume_alert(100000000),
btwn_volume_alert(100000000);
Inputs: on_balance_HighAlert(100000000), on_balance_Low_alert(-100000000);
Input: blockamt(3001);
Inputs:UpColor(DarkGreen), DnColor(Red);
Variable: volume_btwn_bid_ask(0);
Variable: on_balance_tick_vol(0);
variable: vol_gr_or_eq_to_ask(0);
variable: vol_lessoreq_to_bid(0);
If q_Tradevolume < blockamt then
Begin
If q_Last >= q_Ask then vol_gr_or_eq_to_ask = vol_gr_or_eq_to_ask +
q_Tradevolume;
If q_Last >= q_Ask then on_balance_tick_vol = on_balance_tick_vol +
q_Tradevolume;
If q_Last <= q_Bid then vol_lessoreq_to_bid = vol_lessoreq_to_bid +
q_Tradevolume;
If q_Last <= q_Bid then on_balance_tick_vol = on_balance_tick_vol -
q_Tradevolume;
If q_Last < q_Ask And
q_Last > q_bid then volume_btwn_bid_ask = volume_btwn_bid_ask +
q_Tradevolume;
End;
plot1(vol_lessoreq_to_bid, "Bid <=");
plot2(vol_gr_or_eq_to_ask, "Ask >=");
plot3(volume_btwn_bid_ask, "Btwn Bid Ask");
plot4(on_balance_tick_vol, "OB Tick Vol");
If Plot1 >= Plot2 Then
SetPlotcolor(1, DnColor)
Else
SetPlotColor(2, UpColor);
If Plot4 >= 0 Then
SetPlotcolor(4, UpColor)
Else
SetPlotColor(4, DnColor);
{Alerts}
If Plot1 >= bid_volume_alert Then
Alert("Bid Vol. Over the Alert. "+NumToStr(plot1,2));
If Plot2 >= ask_volume_alert Then
Alert("Ask Vol. Over the Alert. "+NumToStr(plot2,2));
If Plot3 >= btwn_volume_alert Then
Alert("Between Vol. Over the Alert "+NumToStr(plot3,2));
If Plot4 >= on_balance_HighAlert Then
Alert("On Balance Vol. Over the High Alert "+NumToStr(plot4,2));
If Plot4 <= on_balance_Low_alert Then
Alert("On Balance Vol. Under the Low Alert "+NumToStr(plot4,2));
Zoran Gayer wrote:
> I trade the SPI and the underlaying contract for the ASX 200 at the Sydney
> exchange.
>
> It is not a large contract by US standards trading from lows of 6,000
> contracts a day to very occasionally over 18,000 per day.
>
> Both actual and tick volume come through as does the bid and asks
> The feed is from Market Cast and is excellent. Recently they have increased
> band width and improved the service even more.
> As far as I can tell all the bids, asks and transactions come through. So
> the indicator should work fine.
>
> Can the volume that is traded be allocated to either "bid" or "ask"
> depending which is taken
> I assume that if it is traded that that it must have transacted either at
> the bid or ask.
>
> The indicator I am after is not bid and ask volume but what is traded at the
> bid and ask.
> This may be a fine distinction but transactions are the reality.
> Bid and ask is not necessarily traded.
> It may be a useful alternate indicator
> It is one of the main things I watch to time an entry.
> An indicator such as this may decrease the need to watch the ticker keenly
> to see how the bid, ask, and transaction relationships are going.
> It may also be useful on bullish and bearish divergences.
> Again the question is it possible to design such an indicator in TS2000i?
>
> Zoran
>
> -----Original Message-----
> From: multitrak@xxxxxxxxxxxxxxxx [mailto:multitrak@xxxxxxxxxxxxxxxx]
> Sent: Friday, August 10, 2001 12:52 AM
> To: omega-list@xxxxxxxxxx
> Subject: Re: Indicator based on BID and ASK
>
> Yeah, but then I thought that Zoran was referring to futures because he
> mentioned "contracts."
>
> Another cruel joke by TS by not letting you get at the data you can see on
> your screen....
>
> MT
>
> At 07:37 AM 8/9/01 -0700, you wrote:
> >I saw that email and almost responded and then I thought maybe it wouldn't
> >work for futures because of lack of volume info, but there might be a way
> to
> >do it for stocks using the Activity Bar Study code in a novel way.
> >
> >BobR
> >
> > > At 08:19 PM 8/9/01 +1000, Zoran Gayer wrote:
> > > >Every time the contract trades on the "ASK" the number of contracts or
> >ticks
|