COULD IT BE SYSTEM

[robert.cummings@xxxxxxxxxxxxxxxx]

This little system gives pretty good results in most markets. I think it 
was written by Mark Brown.

Inputs: RetPcnt(70), Thrust(1);
Vars: lb(0), hb(0), lp(0), hp(0), fb(0);
Vars: Norm(0), RetLevel(0);

IF Date <> Date[1] Then Begin
	lb = -1;
	hb = -1;
	lp = 1000000;
	hp = -1000000;
	fb = CurrentBar;
End;
IF H > hp Then Begin
	hp = H;
	hb = CurrentBar;
End;
IF L < lp Then Begin
	lp = L;
	lb = CurrentBar;
End;
Norm = Average(Range, 20);

IF MarketPosition <= 0 AND Date Tomorrow = Date Then Begin
	IF lb >= fb AND hb > lb AND hb < CurrentBar Then Begin
		IF hp - lp > Thrust * Norm * SquareRoot(hb - lb) Then Begin
			RetLevel = lp + (hp - lp) * RetPcnt / 100;
			IF L > RetLevel AND L[1] > RetLevel Then Begin
				Buy Next Bar at RetLevel Limit;
			End;
		End;
	End;
End;

IF MarketPosition > 0 Then Begin
	ExitLong Next Bar at EntryPrice(0) + (hp - lp) * .50 Limit;
	IF BarsSinceEntry > 16 Then
		ExitLong Next Bar at Market;
End;

IF MarketPosition >= 0 AND Date Tomorrow = Date Then Begin
	IF hb >= fb AND lb > hb AND lb < CurrentBar Then Begin
		IF hp - lp > Thrust * Norm * SquareRoot(lb - hb) Then Begin
			RetLevel = hp - (hp - lp) * RetPcnt / 100;
			IF H < RetLevel AND H[1] < RetLevel Then Begin
			{IF value1 > value1[1] Then}
				Sell Next Bar at RetLevel Limit;
			End;
		End;
	End;
End;

If MarketPosition < 0 Then Begin
	ExitShort Next Bar at EntryPrice(0) - (hp - lp) * .50 Limit;
	IF BarsSinceEntry > 16 Then
		ExitShort Next Bar at Market;

End;

Robert


Attachment Converted: "f:\eudora\attach\Coulditb.ela"