|
PureBytes Links
Trading Reference Links
|
Karile
It would be possible to do what you want, but very time consuming to set up
I think. I have been working on a number of weekly signals that can be used
on daily charts. This is hardly necessary for explorations which can easily
be run in weekly mode, but switching many charts back and forward between
daily and weekly periodicy is a pain. So for some people it is very useful
to display weekly indicators on daily charts.
As I see it there are two major problems to be addressed (for weekly
indicators). The first is how to define the end of a week, and the second is
how to construct and use a weekly data array in conventional functions such
as moving average or average true range. Each function poses it's own set of
problems.
Following is a 'Weekly Frame ADX' indicator that I have been working on. It
may still have some bugs but you'll get some idea of the complexity of
creating just one indicator for a different time frame. One problem that
will crop up if you compress data into two-day slots is how to define the
frame barrier. A "floating" two day frame will produce signals that change
every day so it is necessary to "tie" the frame to even days, odd days, or
some other reference that does not "float". What use is a signal when new
data added changes existing values.
The following indicator includes weekly values of ATR(), Wilders(),
+DI(), -DI(), HIGH and LOW generated from daily data. Other functions
require pulling a few more tricks out of the bag. If you can define how to
"frame" your compressed data then I'm sure it's possible to set up
explorations to achieve what you want.
Roy
{Weekly Frame ADX - Use on Daily Chart}
Pd:=Input("ADX Periods",1,21,5);
W1:=DayOfWeek()=5;
W2:=Alert(W1,2);
W3:=DayOfWeek()<=Ref(DayOfWeek(),-1);
Cw:=If(W1,1,If(W2=0 AND W3,2,0));
WkH:=If(Cw=1,HighestSince(1,W3,H), If(Cw=2,
If(BarsSince(Ref(W3,-1))=4,Ref(HHV(H,5),-1),
If(BarsSince(Ref(W3,-1))=3,Ref(HHV(H,4),-1),
If(BarsSince(Ref(W3,-1))=2,Ref(HHV(H,3),-1),
If(BarsSince(Ref(W3,-1))=1,Ref(HHV(H,2),-1),
Ref(H,-1))))),0));
W0H:=ValueWhen(1,Cw>0,WkH);
W1H:=ValueWhen(2,Cw>0,WkH);
WkL:=If(Cw=1,LowestSince(1,W3,L),If(Cw=2,
If(BarsSince(Ref(W3,-1))=4,Ref(LLV(L,5),-1),
If(BarsSince(Ref(W3,-1))=3,Ref(LLV(L,4),-1),
If(BarsSince(Ref(W3,-1))=2,Ref(LLV(L,3),-1),
If(BarsSince(Ref(W3,-1))=1,Ref(LLV(L,2),-1),
Ref(L,-1))))),0));
W0L:=ValueWhen(1,Cw>0,WkL);
W1L:=ValueWhen(2,Cw>0,WkL);
W0C:=ValueWhen(1,Cw>0,If(Cw=1,C,Ref(C,-1)));
W1C:=ValueWhen(2,Cw>0,If(Cw=1,C,Ref(C,-1)));
PlusDM:=If(W0H>W1H AND W0L>=W1L,W0H-W1H,
If(W0H>W1H AND W0L<W1L AND (W0H-W1H)>(W1L-W0L),
W0H-W1H,0));
MinusDM:=If(W0L<W1L AND W0H<=W1H,W1L-W0L,
If(W0H>W1H AND W0L<W1L AND (W0H-W1H)<(W1L-W0L),
W1L-W0L,0));
W1:=Max(W0H-W0L,Max(Abs(W1C-W0H),Abs(W1C-W0L)));
Tr:=If(Cw>0,If(Cum(Cw>0)=1,W1,PREV)*(1-(1/Pd))+ W1*(1/Pd),PREV);
DIPlus:=If(Cw>0,PREV*(1-(1/Pd))+ PlusDM*(1/Pd),PREV);
DIPlus:=100*DIPlus/Tr;
DIMinus:=If(Cw>0,PREV*(1-(1/Pd)) + MinusDM*(1/Pd),PREV);
DIMinus:=100*DIMinus/Tr;
DIDif:=Abs(DIPlus-DiMinus);
DISum:=DIPlus+DIMinus; W1:=DIDif/DISum;
W2:=If(Cw>0,PREV*(1-(1/Pd))+W1*(1/Pd),PREV); PREC(100*W2,2);
----- Original Message -----
From: "Karile" <karile@xxxxxxxxxx>
To: <Metastockusers@xxxxxxxxxxxxxxx>
Sent: Thursday, October 10, 2002 9:34 PM
Subject: Re: [Metastockusers] Re: 2 days Explorations
Claude, Roy and Patrick
Being a frenchwoman, I sometimes have difficulty to speak english correctly.
As Claude said, I would like to perform an exploration on the basis of data
for every other day (2 day).
Your help is appreciated,
Karile
----- Original Message -----
From: Patrick McGaughey
To: Metastockusers@xxxxxxxxxxxxxxx
Sent: Thursday, October 10, 2002 4:13 AM
Subject: Re: [Metastockusers] Re: 2 days Explorations
would a 3 line-break display give her what she wants?
Patrick
----- Original Message -----
From: -= Chris ß =-
To: Metastockusers@xxxxxxxxxxxxxxx
Sent: Thursday, October 10, 2002 11:04 AM
Subject: Re: [Metastockusers] Re: 2 days Explorations
Roy,
I think Karile means to perform an exploration on the basis of data
for every other day(2 day), akin to doing a weekly (7 day - 5 open
days), say Friday's close (Weekly compressed data).
I myself sometime look at the data compressed... I don't trade on that
basis, but it removes the "visual" static.
On Thu, 10 Oct 2002 10:34:47 +1300, you wrote:
> Karile
>
> > I would like to perform an exploration with a 2 days data
compression
>
> I don't understand what you mean. Can you explain more fully? (the
> "Explanation for Idiots" version please)
To unsubscribe from this group, send an email to:
Metastockusers-unsubscribe@xxxxxxxxxxx
Your use of Yahoo! Groups is subject to the Yahoo! Terms of Service.
Yahoo! Groups Sponsor
ADVERTISEMENT
To unsubscribe from this group, send an email to:
Metastockusers-unsubscribe@xxxxxxxxxxx
Your use of Yahoo! Groups is subject to the Yahoo! Terms of Service.
------------------------ Yahoo! Groups Sponsor ---------------------~-->
Sell a Home for Top $
http://us.click.yahoo.com/RrPZMC/jTmEAA/MVfIAA/zMEolB/TM
---------------------------------------------------------------------~->
To unsubscribe from this group, send an email to:
Metastockusers-unsubscribe@xxxxxxxxxxx
Your use of Yahoo! Groups is subject to http://docs.yahoo.com/info/terms/
|