[RT] DTA High5 Part1

["BobR" <bobrabcd@xxxxxxxxxxxxx>]

Caveates and disclaimers:
This code is free, there is no guaranteed support for it, fixed parameters
may change as some of the components change.  It has some novel features
some might find useful and is a bit different than the standard fare
indicator.  It is designed as an intraday indicator with multiple data
series.  The code text is below and is attached as .ELS.

Enjoy,
BobR

{
CAVEATE:
Chart data must be setup in this sequence for the indicator to
reference it properly.

data1= S&P 500 current futures contract or other tradeable
data2= TRIN
data3= VIX {data does not exist for at least until 15 minutes after the
open}
data4= TICK
data5= COMPQ
data6= MER

Display characteristics:
Plots red dots before VIX is available on bar periods less than
15 minutes as a warning that all data is not available yet for
a valid indicator reading.  Plots magenta dots at top of hour and
yellow dots at all other times}

Inputs:
  StartTime(0946), {set for one minute or one bar greater than }
                   {when VIX data is available, i.e. 0946 on five minute
bars}
  Bullish(2.5),
  Neutral(0),
  Bearish(-2.5);

vars: Trin(0),VIX(0),TICK(0),COMPQ(0),MER(0),Tape(0);

Vars: PC2(0), PC3(0), PC4(0), PC5(0), PC6(0);

If Date<>Date[1] then begin
  PC2 = C[1] of Data2;
  PC3 = C[1] of Data3;
  PC4 = C[1] of Data4;
  PC5 = C[1] of Data5;
  PC6 = C[1] of Data6;
End;

{Trin- absolute}
Value1 = c of data2;
If Value1<=0.6                 then Trin=+1.0 else
If Value1<=0.8 and Value1> 0.6 then Trin=+0.5 else
If Value1> 0.8 and Value1<=1.0 then Trin= 0.0 else
If Value1> 1.0 and Value1< 1.3 then trin=-0.5 else
If Value1>=1.3                 then Trin=-1.0;

{VIX - relative}
Value1 = c of data3 - PC3;
If Value1<=-1.2                  then VIX=+1.0 else
If Value1< -0.8 and Value1>-1.20 then VIX=+0.5 else
If Value1>=-0.8 and Value1<=0.80 then VIX= 0.0 else
If Value1>  0.8 and Value1< 1.00 then VIX=-0.5 else
If Value1>=1.0                   then VIX=-1.0;

{TICK - absolute}
Value1 = c of data4;
If Value1>=+500                  then TICK=+1.0 else
If Value1> +200 and Value1< +500 then TICK=+0.5 else
If Value1>=-200 and Value1<=+200 then TICK= 0.0 else
If Value1< -200 and Value1> -500 then TICK=-0.5 else
If Value1<=-500                  then TICK=-1.0;

{COMPQ - relative}
Value1 = c of data5-PC5;
If Value1>=+20                 then COMPQ=+1.0 else
If Value1> +15 and Value1< +20 then COMPQ=+0.5 else
If Value1>=-15 and Value1<=+15 then COMPQ= 0.0 else
If Value1< -15 and Value1> -20 then COMPQ=-0.5 else
If Value1<=-20                 then COMPQ=-1.0;

{MER-relative}
Value1 = c of data6-PC6;
If Value1>=+1.5                  then Mer=+1.0 else
If Value1< +1.5 and Value1> +1.0 then MER=+0.5 else
If Value1>=-1.0 and Value1<=+1.0 then MER= 0.0 else
If Value1< -1.0 and Value1>=-1.5 then MER=-0.5 else
If Value1<=-1.5                  then MER=-1.0;

Tape = Trin + VIX + TICK + MER + COMPQ;

Plot1(Tape,"Tape");

If Time<StartTime then setplotcolor(1,red)
                  else Setplotcolor(1,yellow);

If Mod(Time[1],100)>Mod(Time,100)then Setplotcolor(1,magenta);


Plot2(bullish,"Bullish");
Plot3(Neutral,"Neutral");
Plot4(Bearish,"Bearish");

{
Credits go to:
Mohan http://www.daytradersaction.com
BobR http://www.oextrader.com/sigma_trader
Clyde Lee http://www.theswingmachine.com
}

------------------------ Yahoo! Groups Sponsor ---------------------~-->
Make Money Online Auctions! Make $500.00 or We Will Give You Thirty Dollars for Trying!
http://us.click.yahoo.com/yMx78A/fNtFAA/i5gGAA/zMEolB/TM
---------------------------------------------------------------------~->

To unsubscribe from this group, send an email to:
realtraders-unsubscribe@xxxxxxxxxxxxxxx

 

Your use of Yahoo! Groups is subject to http://docs.yahoo.com/info/terms/ 


Attachment:
DTA High5.gif
Description: GIF image
Attachment:

Attachment: Description: "Description: Binary data"

Attachment: Description: "DTA_HIGH5.ELS"