Lindahl Formation EL code - here it is

[alex@xxxxxxxxxxxxxx (Alex Matulich)]

Philip Schmitz asked about coding the Lindahl formation.  I've
given it a shot, below.  Save the following as a signal in the EL
PowerEditor.

The formation occurs more often than I thought it would.  However, I
can't see that it's any more reliable an entry signal than flipping
a coin.  Signals appear without respect to whether the market will
go up, down, or sideways after the signal.

If anybody finds it useful, please tell me how.  Personally I think
pattern recognition techniques are nice for learning about markets
but not particularly useful for making reliable trades.


{***************************************
 Written by: Alex Matulich
 Description: Lindahl pattern by Colin Alexander
****************************************}

{The Lindahl Rule 
Buying: Within nine bars from the low of the formation:
(a) price must exceed the high of the bottom bar;
(b) price must then take out the low of the preceding bar;
(c) on entry day, price must take out the high the preceding bar and
    close above the preceding bar's close and the current bar's open
Opposite for selling.
This formation may be completed in as few as 3 bars or as many as 9.}

variables: newlowbar(10), newhibar(10), lowbar(0), hibar(0), b(0);

if low < low[1] then newlowbar = 0 else newlowbar = newlowbar[1] + 1;
if high > high[1] then newhibar = 0 else newhibar = newhibar[1] + 1;

lowbar = lowestbar(low, 9);
if low[lowbar] < low[lowbar+1] and lowbar > 1 then begin  {low identified}
	b = highestbar(high, lowbar-1);
    if high[b] > high[lowbar]                                   {(a)}
       and newlowbar < b                                        {(b)}
       and high > high[1] and close > close[1] and close > open {(c)}
         then buy("L") tomorrow open;
end;

hibar = highestbar(high, 9);
if high[hibar] > high[hibar+1] and hibar > 1 then begin
	b = lowestbar(low, hibar-1);
    if low[b] < low[hibar]
       and newhibar < b
       and low < low[1] and close < close[1] and close < open
        then sell("S") tomorrow open;
end;