Re: Plot scaling

[Bob Perry <bobperry@xxxxxxxxxxx>]

Here's something that might help...  it plots the 2 1/2% and 5% LD only
if the price is within earshot.
Just cut and paste.

Bob Perry
San Jose, CA



{	Bob Perry 12/94,9/97,12/98,11/00
	Close of Yesterday:		Cyan, point, weight=3
	Open of today: 			White, point, weight=3
	Floor Traders Pivot:	Brown, point, weight=3
	LimitMove:				Blue, cross, weight=2
}

Inputs:	PriceLev(20), IsOpenOn(True), IsClosOn(True), True_C1(0),
LimitMove1(65), LimitMove2(130);
Vars:	HH(c), LL(c), CC(c), C1(c), O1(c), P(c), LM1(0), LM2(0), Reset(0),
LM1on(0), LM2on(0);

If Date <> Date[1] then begin
	Reset = 0;
	LM1on = 0;
	LM2on = 0;
End;


If time >= Sess1StartTime and time <= Sess1EndTime then begin
	If Reset = 0 then begin
		C1 = CC;
		O1 = Open;
		LM1 = C1 - LimitMove1;
		LM2 = C1 - LimitMove2;
		P = (HH+LL+C1)/3;
		{Plot1(P,"Pivot");		Plot floor Trader Pivot on first bar}
		HH = 0;
		LL = 999999;
		Reset = 1;
	End;

	If High > HH then HH = High;
	If Low < LL then LL = Low;
	CC = IFF(True_C1=0,Close,True_C1);
	


	If (AbsValue(P-H) < PriceLev) or (AbsValue(L-P) < PriceLev) then begin
		Plot1(P,"Pivot");
	End;

	If IsOpenOn = True then begin
		If (AbsValue(O1-H) < PriceLev) or (AbsValue(L-O1) < PriceLev) then
begin
			Plot2(O1,"OpenToday");
		End;
	End;

	If IsClosOn = True then begin
		If (AbsValue(C1-H) < PriceLev) or (AbsValue(L-C1) < PriceLev) then
begin
			Plot3(C1,"Close[1]");
		End;
	End;

	If Low < LM1 then LM1on = 1;
	If (LM1on = 0) AND (LimitMove1 <> 0) AND (time <= MinutesToTime(
TimeToMinutes(Sess1StartTime) + 360)) then begin
		If (AbsValue(LM1-H) < PriceLev) or (AbsValue(L-LM1) < PriceLev) then
begin
			Plot4(LM1,"Limit");
		End;
	End;

	If Low < LM2 then LM2on = 1;
	If (LM2on = 0) AND (LimitMove2 <> 0) AND (time <= MinutesToTime(
TimeToMinutes(Sess1StartTime) + 360)) then begin
		If (AbsValue(LM2-H) < PriceLev) or (AbsValue(L-LM2) < PriceLev) then
begin
			Plot4(LM2,"Limit");
		End;
	End;
End;

{- - - EOF - - -}