Std deviation Exit

["Michael Stewart" <MPST@xxxxxxxxxxxxx>]

This std deviation trailing and profit taking exits appear to decrease Avg
trade win or loss and ROA. Exits losing trades quickly and cuts winning
trades short, which would imply that in order for a system which uses them
to be profitable and cover slippage and commissions a high % of winning
trades are required.

But how does that sit alongside letting your profitable trades run and
cutting the losers short?  Apart from widening the std band and possibly
using discretion on the exit would anyone who uses (or has used) a std d
exit have any thoughts to add?


{ Profit Taking Stop}

Inputs: Factor(3),SDLen(30);
VAR: VolIndex(0), LongLimit(0), LongStop(0), ShortLimit(0), ShortStop(0);

VolIndex = Factor*StdDev(Close - Close[1],SDLen);

IF MarketPosition(0)=1 THEN
   BEGIN
      LongLimit = EntryPrice(0) + VolIndex;
      LongStop = EntryPrice(0) - VolIndex;
      ExitLong ("Exit #2 Ln +") Next Bar at LongLimit Limit;
      ExitLong ("Exit #2 Ln -") Next Bar at LongStop  Stop;
   END;

IF MarketPosition(0)=-1 THEN
   BEGIN
      ShortLimit = EntryPrice(0) - VolIndex;
      ShortStop = EntryPrice(0) + VolIndex;
      ExitShort ("Exit #2 Sh +") Next Bar at ShortLimit Limit;
      ExitShort ("Exit #2 Sh -") Next Bar at ShortStop  Stop;
   END;

   { Trailing Stop}

VAR: BestLong(0), LongExit(0), BestShort(0), ShortExit(0);

IF MarketPosition(0)=1 THEN
   BEGIN
      BestLong = MaxPositionProfit / (CurrentContracts * BigPointValue) +
EntryPrice(0);

      LongExit = BestLong - 3*StdDev(Close - Close[1], 75); {30}

      ExitLong ("Exit #1-Lng") Next Bar at LongExit Stop;
   END;

IF MarketPosition(0)=-1 THEN
   BEGIN
      BestShort = EntryPrice(0) - MaxPositionProfit / (CurrentContracts *
BigPointValue);

      ShortExit = BestShort + 3*StdDev(Close - Close[1], 75); {30}

      ExitShort ("Exit #1-Sht") Next Bar at ShortExit Stop;
   END;