|
PureBytes Links
Trading Reference Links
|
Sure - here it is:
Buy when the Rainbow Oscillator looks good, sell when it looks bad.
MetaStock -> Tools -> Indicator Builder -> New
-> copy & paste complete formula between "---8<---" lines.
==================
Rainbow Oscillator
==================
---8<-----------------------------------------
{ Rainbow Oscillator v2.0
Incorporating automatic overBought/Sold levels.
Trade at own risk.
Default values result in an identical plot
to MetaStock v10's RMO "SwingTrd1" indicator.
©Copyright 2006 Jose Silva.
The grant of this license is for personal use
only - no resale or repackaging allowed.
http://www.metastocktools.com }
{ Indicator Inputs }
y:=Input("Smoothing SMA periods",1,252,2);
pds:=Input("HHV/LLV lookback periods",1,252,10);
plot:=Input("plot: [1]Oscillator, [2]Signals",1,2,1);
type:=Input("signals: [1]Higher Lo, Lower Hi, [2]OBought/Sold",1,2,1);
{ Rainbow Oscillator,
http://www.traders.com/documentation/feedbk_docs/archive/0897/TradersTips/
Tips9708.html }
x:=(C-(
Mov(C,y,S)+
Mov(Mov(C,y,S),y,S)+
Mov(Mov(Mov(C,y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(C,y,S),y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(Mov(C,y,S),y,S),y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(Mov(Mov(C,y,S),
y,S),y,S),y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(Mov(Mov(Mov(C,y,S),
y,S),y,S),y,S),y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(Mov(Mov(Mov(Mov(C,y,S),
y,S),y,S),y,S),y,S),y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(Mov(Mov(Mov(Mov(Mov(C,y,S),
y,S),y,S),y,S),y,S),y,S),y,S),y,S),y,S)+
Mov(Mov(Mov(Mov(Mov(Mov(Mov(Mov(Mov(Mov(C,y,S),
y,S),y,S),y,S),y,S),y,S),y,S),y,S),y,S),y,S))
/10)/Max(HHV(C,pds)-LLV(C,pds),.000001)*100;
{ Automatic overBought/Sold levels }
avg:=Cum(x)/Cum(IsDefined(x));
pk:=Ref(x,-1)=HHV(x,3) AND Ref(x,-1)>avg;
pkVal1:=ValueWhen(1,pk,Ref(x,-1));
pkVal2:=ValueWhen(2,pk,Ref(x,-1));
pkValAvg:=Cum(pkVal1)/Cum(IsDefined(pkVal1));
tr:=Ref(x,-1)=LLV(x,3) AND Ref(x,-1)<avg;
trVal1:=ValueWhen(1,tr,Ref(x,-1));
trVal2:=ValueWhen(2,tr,Ref(x,-1));
trValAvg:=Cum(trVal1)/Cum(IsDefined(trVal1));
{ OverBought/Sold signals }
entry:=x<trValAvg;
exit:=x>pkValAvg;
{ Higher troughs / lower peaks signals }
entry:=If(type=2,entry,
trVal1>trVal2 AND x>pkVal1);
exit:=If(type=2,exit,
pkVal1<pkVal2 AND x<trVal1);
{ Clean signals }
init:=Cum(IsDefined(entry+exit))=1;
bin:=ValueWhen(1,entry-exit<>0 OR init,entry);
long:=bin*(Alert(bin=0,2)
OR entry*Cum(entry)=1);
short:=(bin=0)*(Alert(bin,2)
OR exit*Cum(exit)=1);
{ Plot in own window }
If(plot=1,pkValAvg,0); {Grey}
If(plot=1,avg,0); {Grey}
If(plot=1,trValAvg,0); {Grey}
If(plot=1,x,long-short)
---8<-----------------------------------------
jose '-)
http://www.metastocktools.com
--- In equismetastock@xxxxxxxxxxxxxxx, "stock
market" <stockmarket1974@xxx> wrote:
>
> hi jose,
> thanks for the great gift of RMS. can we have the RMO system as well
> somehow. i use the v8.0
> regards
> joshik
>
>
>
> On 2/8/07, Jose Silva <josesilva22@xxx> wrote:
>
> RMO made you eggs and toast?
>
> Sheezzz...I'll have to work on RBS to do better.
>
> jose '-)
> http://www.metastocktools.com
>
>
>
> --- In equismetastock@xxxxxxxxxxxxxxx,
> eqmts <no_reply@> wrote:
>
> ...and the world was amazed. However for all of u traders, especially
> for u Jose, and why not for u wannabe traders, i must inform u that i
> belive that RBS is not as good as RMO. Here is the reasons why: after
> reading a post from a forum (i tried hard to forget where it was and
> finaly i did) in wich a fellow wannabe.. stated that RMO has made him
> $20000 last week and this week is $5000 up or something like that (i
> don`t remember exactly the numbers) and his advice for another
> wannabe was, and i quote, "go get it tiger, it worth all the money",
> i decided that at least i could look at this RMO so i`ve struggled
> enough and finnaly i get it. After installing it, it was late so i
> decided that i should go to sleep. Next morning when i wake up guess
> what? RMO has made me a brakfast consisting of two egs with toasted
> bread and a tea, and more than that it has mad me a lot of $$ with my
> computer shut down. Now i must give u wannabes the same advice "go
> get it tiger". Jose can RBS do what RMO did?
> From now on i will buy every pluggin that equis will make. Anybody
> lend me some money?
>
>
>
> --- In equismetastock@xxxxxxxxxxxxxxx,
> "Jose Silva" <josesilva22@> wrote:
>
> Hot on the heels of MetaStock v10's RMO trading system, comes the
> latest craze - the Ramona Bands Strategy.
>
>
> Instructions (please read first!):
> http://www.metastocktools.com/downloads/RBS.txt
>
> Setup file:
> http://www.metastocktools.com/downloads/RBS.zip
>
> Chart sample:
> http://www.metastocktools.com/downloads/RBS.png
>
>
> Should it be bundled with MS v11? ;)
> Please take a (free) look at it, and share your thoughts on it
> here. :)
>
>
>
> jose '-)
> http://www.metastocktools.com
Yahoo! Groups Links
<*> To visit your group on the web, go to:
http://groups.yahoo.com/group/equismetastock/
<*> Your email settings:
Individual Email | Traditional
<*> To change settings online go to:
http://groups.yahoo.com/group/equismetastock/join
(Yahoo! ID required)
<*> To change settings via email:
mailto:equismetastock-digest@xxxxxxxxxxxxxxx
mailto:equismetastock-fullfeatured@xxxxxxxxxxxxxxx
<*> To unsubscribe from this group, send an email to:
equismetastock-unsubscribe@xxxxxxxxxxxxxxx
<*> Your use of Yahoo! Groups is subject to:
http://docs.yahoo.com/info/terms/
|
