[EquisMetaStock Group] Re: Fake and break

["Jose Silva" <josesilva22@xxxxxxxxx>]

Try this MS code:

---8<-----------------------------------

{ Custom Buy signals - trade at own risk.
  http://www.metastocktools.com }

{ Variables }
SMAperiods:=200;
LLVperiods:=20;
RangePeriods:=4;
DelayPeriods:=0;


{ Today's Close is greater than upward
  200 period SMA }

SMA:=Mov(C,SMAperiods,S);
cond1:=C>SMA AND SMA>Ref(SMA,-1);


{ Today's Close is greater than today's Open
  (*hindsight condition*!),
  AND greater than yesterday's Close }

cond2:=C>O AND C>Ref(C,-1);


{ Yesterday's Close is less than
  yesterday's Open }

cond3:=Ref(C<O,-1);


{ Yesterday was a new 20 day low
  AND the day before was not a new 20 day low }

cond4:=Ref(C,-1)=LLV(C,LLVperiods)
 AND Ref(C,-2)<>LLV(C,LLVperiods);


{ Today's or yesterday's price bar (High-Low
  range) is the largest of the last four days }

range:=H-L;
cond5:=Max(range,Ref(range,-1))
 =HHV(range,RangePeriods);


{ Composite condition }
buy:=Ref(cond1*cond2*cond3*cond4*cond5,
 -DelayPeriods);

{ Plot in own window }
0;buy

---8<-----------------------------------


jose '-)
http://www.metastocktools.com




--- In equismetastock@xxxxxxxxxxxxxxx, 
"mrs_grobler" <mrs_grobler@xxx> wrote:
>
> Can anyone assist me by providing me the following in metastock 
> formula?
> 
>
> Buying condition
>
> Today's close is greater than the uptrending 200 period moving
> average Today's close is greater than today's open AND today's
> close is greater than yesterday's close
>
> Yesterday's close is less than yesteday's open
>
> Yesterday was a new 20 day low AND the day before was not a new
> 20 day low
>
> Today or yesterday's price bar is the largest range of the last
> four days







 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/equismetastock/

<*> Your email settings:
    Individual Email | Traditional

<*> To change settings online go to:
    http://groups.yahoo.com/group/equismetastock/join
    (Yahoo! ID required)

<*> To change settings via email:
    mailto:equismetastock-digest@xxxxxxxxxxxxxxx 
    mailto:equismetastock-fullfeatured@xxxxxxxxxxxxxxx

<*> To unsubscribe from this group, send an email to:
    equismetastock-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/