RE: [EquisMetaStock Group] Hurst Channel

["Andrew Tomlinson" <andrew_tomlinson@xxxxxxxxxxx>]

Andy

Thank you for a very good summary of Hurst-based techniques.

I agree that fixed-width channels are limiting and that  % and ATR-based
channels both work well. I have also found in some markets that it is good
to build in the possibility of a different ATR multiple or % on the upside
and the downside. Upside and downside volatility are usually different. I
also sometimes use the typical price rather than close and a bit of
additional ATR smoothing, so a simple version might be:

P1:=Input("No of bars:",1,500,21);
P2:=Input("ATR multiple",0.5,10,2.5);
P3:=Input("Downside ATR skew",0,2,1.0);
TypPrice:=(O+H+L+C)/4;
MA:=Ref(Mov(TypPrice,P1,TRI),(P1+1)/2);
BTop:=MA+Mov(Ref(P2*ATR(P1),(P1+1)/2),5,S);
BBottom:=MA-Mov(Ref(P2*P3*ATR(P1),(P1+1)/2),5,S);

MA;
BTop;
BBottom;

You can apply a similar concept to %.

Andrew


-----Original Message-----
From: equismetastock@xxxxxxxxxxxxxxx [mailto:equismetastock@xxxxxxxxxxxxxxx]
On Behalf Of Andy
Sent: Wednesday, December 14, 2005 4:58 AM
To: equismetastock@xxxxxxxxxxxxxxx
Subject: RE: [EquisMetaStock Group] Hurst Channel



Wallace,



Here's the code I use for CMA channels. Uses a triangular MA for extra
smoothing as per Andrew's comments. You can replace the TRI with S if you
want to use simple MA for comparison. I generally stick with the fixed
percentage channel.as opposed to Hurst who advocates a fixed absolute width.
That bit seems slightly illogical to me as a higher price usually brings
higher absolute volatility. If you plot the fixed % on a semi-log plot then
you will get a fixed width.



Hope it helps.



Andy



--------------



{Centred MA Envelopes (Triangular)}



{half-span CMA will highlight desired wavelength}

{further 1.5 factor used due to Tri MA double smoothing}

{odd periods ensure there is a valid centred reference point.

Achieved by last line of 'P1' code}



{Periods}

P1:=Input("Highlight/Show Wavelength =",3,10000,31);

X:=Input("NB, contains all cycles with WLth less than this",0,0,0);

P1:=P1/2;

P1:=round(P1*1.5);

P1:=LastValue(If(Frac(P1/2)=0,P1+1,P1));



{Other Inputs}

Y:=Input("Envelope Width Basis [1]#ATRs [2]% [3]price",1,3,2);

Z:=Input("Envelope Width",0,1000,0.005);



{moving average}

MA:=Mov(C,P1,TRI);



{envelope width}

X:=If(Y=1,Z*Mov(ATR(1),P1,S),If(Y=2,MA*Z/100,Z));



{envelopes}

EU:=MA+X;

EL:=MA-X;



{Centre Everything}

PC:=LastValue((P1-1)/2);

CMA:=Ref(MA,PC);

CEU:=Ref(EU,PC);

CEL:=Ref(EL,PC);



CMA;CEU;CEL;





----- Original Message -----

From: murusprimus <mailto:sace@xxxxxxx>

To: equismetastock@xxxxxxxxxxxxxxx

Sent: Wednesday, December 14, 2005 4:07 AM

Subject: [EquisMetaStock Group] Hurst Channel



Hi, does anyone have a Hurst Channel formula/s they would post please.

TIA. Wallace












------------------------ Yahoo! Groups Sponsor --------------------~--> 
Try Online Currency Trading with GFT. Free 50K Demo. Trade 
24 Hours. Commission-Free. 
http://us.click.yahoo.com/RvFikB/9M2KAA/U1CZAA/BefplB/TM
--------------------------------------------------------------------~-> 

 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/equismetastock/

<*> To unsubscribe from this group, send an email to:
    equismetastock-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/