Re: [EquisMetaStock Group] Formula for monthly hhv question

["Roy Larsen" <rlarsen@xxxxxxxxxxxxxx>]

Hi Belice2003

 

 

Here's a bare-bones Monthly OHLC indicator that will provide the high for each month on the last bar of the month, as well as the other prices

 

  {Monthly OHLC}
  {© 2005 Roy Larsen, www.metastocktips.co.nz}
  {use on daily charts}
F:=PeakBars(1,Zig(DayOfMonth(),1,$),1)=0 OR
Cum(1)=LastValue(Cum(1));
M:=ValueWhen(2,1,F);
Hm:=ValueWhen(1,F,HighestSince(1,M,H));
Lm:=ValueWhen(1,F,LowestSince(1,M,L));
Cm:=ValueWhen(1,F,C);
Om:=ValueWhen(1,F,ValueWhen(1,M,O));
Om:=ValueWhen(1,Om>0,Om);
Hm:=ValueWhen(1,Hm>0,Hm);
Lm:=ValueWhen(1,Lm>0,Lm);
Om; Hm; Lm; Cm;

 

Reducing it to just the monthly HIGH gives this.

 

  {Monthly HIGH}
  {© 2005 Roy Larsen, www.metastocktips.co.nz}
  {use on daily charts}
F:=PeakBars(1,Zig(DayOfMonth(),1,$),1)=0 OR
Cum(1)=LastValue(Cum(1));
M:=ValueWhen(2,1,F);
Hm:=ValueWhen(1,F,HighestSince(1,M,H));
ValueWhen(1,Hm>0,Hm); 

 

Hope this helps.

 

 

Regards

 

Roy

 

 

----- Original Message -----

From: belice2003

To: equismetastock@xxxxxxxxxxxxxxx

Sent: Tuesday, October 11, 2005 6:58 AM

Subject: [EquisMetaStock Group] Formula for monthly hhv question

Hi fellow Metastock users,

I'm trying to create an indicator in locating hhv of stocks in any
given month using daily chart.  By using HHV(H,25)[just a part of my
formula], it would have solved the problem since there are 25 trading
days per month.  But when there's a holiday during the month, that's
where the problem comes in because it throws off my analysis.  It
would have been easy for me to locate such values when I switch to the
monthly chart; but that's not what I wanted.  Thanks in advance for
anyone who can give me assistance!

---

YAHOO! GROUPS LINKS

•  Visit your group "equismetastock" on the web.
   
•  To unsubscribe from this group, send an email to:
   equismetastock-unsubscribe@xxxxxxxxxxxxxxx
   
•  Your use of Yahoo! Groups is subject to the Yahoo! Terms of Service.

---