Re: [EquisMetaStock Group] full Moon/New Moon indicator

[Claud Baruch <claudb@xxxxxxxxxxxx>]

Here's my up-to-date chart of the S&P.

http://pw1.netcom.com/~claudb/Lunar.gif

Claud

Dusant wrote:

From my archives. Have not tried it, so cannot vouch for accuracy. However, Jose has a reputation of not placing anything here without adequate testing.

 

Plot as a histogram.

 

{ Full/New Moon signals indicator MkV }
{ Accurate to within 1 minute per 69 years }
{ ©Copyright 2002-2004 jose silva }
{ http://users.bigpond.com/prominex/pegasus.htm }

 

{ Plots +1 signal on Full Moon; -1 on New Moon }
{ If FM/NM falls on a holiday or weekend,
  signal is plotted on the nearest trading day }

 

Span:=Input("Full/New Moon signal, total span in days",1,9,1);
TZ:=Input("Time Zone (-12 to +12hrs)",-12,12,-10);

 

LunarMonth:=29.530589;
Offset:=7.254621;

 

leap:=Frac(Year()/4)=0 AND Frac(Year()/100)<>0 OR Frac(Year()/400)=0;
y:=Year()*365+Int(Year()/4) -Int(Year()/100)+Int(Year()/400);
m:=
 If(Month()=2,31-leap,
 If(Month()=3,59,
 If(Month()=4,90,
 If(Month()=5,120,
 If(Month()=6,151,
 If(Month()=7,181,
 If(Month()=8,212,
 If(Month()=9,243,
 If(Month()=10,273,
 If(Month()=11,304,
 If(Month()=12,334,
 -leap)))))))))));
CurrentDay:=y+m+DayOfMonth()+TZ/24-Offset;

 

FM:=Frac(CurrentDay/LunarMonth);
NM:=Frac(FM+0.5);

 

0;Ref(Alert(FM>Ref(FM,1),Span),Span/2)+ -Ref(Alert(NM>Ref(NM,1),Span),Span/2)

 

Dusant
http://www.geocities.com/cooldush

----- Original Message -----

From: Al Dina

To: equismetastock@xxxxxxxxxxxxxxxx

Sent: Sunday, June 26, 2005 5:49 AM

Subject: [EquisMetaStock Group] full Moon/New Moon indicator

Hello,

 

A while ago, I believe that Jose or someone else posted the code for the Full Moon/New Moon.  Does anybody have that code and do they know if it is accurate? 

 

Any help would be appreciated.

 

Thanks,

Al

---

Free antispam, antivirus and 1GB to save all your messages
Only in Yahoo! Mail: http://in.mail.yahoo.com

---

YAHOO! GROUPS LINKS

•  Visit your group "equismetastock" on the web.
   
•  To unsubscribe from this group, send an email to:
   equismetastock-unsubscribe@xxxxxxxxxxxxxxx
   
•  Your use of Yahoo! Groups is subject to the Yahoo! Terms of Service.

---