|
PureBytes Links
Trading Reference Links
|
Thanks Norman (and Jose), it looks like it should do exactly what I
need. I'll remember to check his site next time!
regards,
kaj
ruagoodp wrote:
Hi Kaj,
I guess jose won't mind me posting his formula as he is on holidays
now. You could also find other useful formulae from his site
www.metastocktools.com where you will also find formulae from Roy Larsen.
Here is the formulae for exploration of true Highs and Lows(copyright
Jose Silva)
==================
True 52-Week Highs
==================
---8<---------------------------
52-Week true Highs
*Input today's data date in filter section!*
Only stocks trading since 52 weeks ago are considered candidates for
this exploration.
Rem out code {AND V>0} in filter section to explore for non-volume
instruments, such as indices and Forex.
{ ©Copyright 2003 Jose Silva }
{ http://www.metastocktools.com }
------------------
Column A: Close
CLOSE
------------------
Column B: % change
{ % change from previous Close }
Int((C/Ref(C,-1)-1)*1000+.5)/10
------------------
Column C: $'000
{ today's turnover in $'000 }
Int((MP()*V+500)/1000)
------------------
Filter:
{ Today's data date, user input section }
day:= 18; { today (1~31) }
mth:= 9; { current month (1~12) }
yr:= 2003; { current year, eg 2003 }
{ *********************************** }
active:=Year()>yr-1
OR (Year()=yr-1 AND (Month()>mth
OR Month()=mth AND DayOfMonth()>=day));
start:=active AND Alert(active=0,2);
DayOfMonth()=day
AND Month()=mth
AND Year()=yr
AND Highest(start)
AND C>Ref(HighestSince(1,start,C),-1)
AND V>0
---8<---------------------------
=================
True 52-Week Lows
=================
---8<---------------------------
52-Week true Lows
*Input today's data date in filter section!*
Only stocks trading since 52 weeks ago are considered candidates for
this exploration.
Rem out code {AND V>0} in filter section to explore for non-volume
instruments, such as indices and Forex.
{ ©Copyright 2003 Jose Silva }
{ http://www.metastocktools.com }
------------------
Column A: Close
CLOSE
------------------
Column B: % change
{ % change from previous Close }
Int((C/Ref(C,-1)-1)*1000-.5)/10
------------------
Column C: $'000
{ today's turnover in $'000 }
Int((MP()*V+500)/1000)
------------------
Filter:
{ Today's data date, user input section }
day:= 18; { today (1~31) }
mth:= 9; { current month (1~12) }
yr:= 2003; { current year, eg 2003 }
{ *********************************** }
active:=Year()>yr-1
OR (Year()=yr-1 AND (Month()>mth
OR Month()=mth AND DayOfMonth()>=day));
start:=active AND Alert(active=0,2);
DayOfMonth()=day
AND Month()=mth
AND Year()=yr
AND Highest(start)
AND C<Ref(LowestSince(1,start,C),-1)
AND V>0
---8<---------------------------
Cheers
Norman
--- In Metastockusers@xxxxxxxxxxxxxxx, kaj444s <kaj444s@xxxx> wrote:
Ok Norman, thanks. I felt kinda like I just walked into the middle
of a
conversation. I am months behind reading this list, but as I said, a
search did not turn up an email with the scans you referenced.
I have no doubt Roy's newsletter is beneficial, and I 'm surprised I
haven't yet subscribed. It's just that I've been overwhelmed with
reading material for the last year or so and don't want to add anything
more at this point, even if it doesn't take long to read.
The subject of your email caught my eye because I wanted a 52 week high
exploration that worked on daily bars, and did not simply estimate the
number of trading days in a year by use of the HHV function. Not that
the HHV is a bad way to go. In fact the occasional miss by the HHV
would probably be very rare.
I checked here because I was hoping not to have to reinvent the
wheel.
Probably in the time it took to conceive and write this exploration, I
could have read a couple of Roy's issues!
This morning I wrote the following scan. It uses the LastValue
function
and seems to do what I want. I've run it and eyeballed several dozen
of the charts it picked up, and so far don't see any problems at this
point,. But I'd like to know if someone does. I have no idea if this
is similar to Roy's, or inferior in some way. But regardless, I don't
see any problem posting my work here.
I'm using the highs and lows, but some might prefer to use the close.
My apologies if the formatting of this email is bad when you receive
it;
Firefox email client sometimes does a poor job.
- 52 WEEK HIGH / LOW SCAN -
-colA-
{New Highs)
date:=(Month()*1000000)+(DayOfMonth()*10000)+Year();
1YearAgo:=
Ref(date=LastValue(date-1) OR
date=LastValue(date-1)+10000 OR
date=LastValue(date-1)+11000 OR
date=LastValue(date-1)+12000 OR
date=LastValue(date-1)+13000 ,-1);
52WeekHigh:=HighestSince(1,1YearAgo=1 AND Ref(1YearAgo,-1)=0,H);
New52WeekHigh:= H>Ref(52WeekHigh,-1);
New52WeekHigh
---------------------
-colB-
{New Lows)
date:=(Month()*1000000)+(DayOfMonth()*10000)+Year();
1YearAgo:=
Ref(date=LastValue(date-1) OR
date=LastValue(date-1)+10000 OR
date=LastValue(date-1)+11000 OR
date=LastValue(date-1)+12000 OR
date=LastValue(date-1)+13000 ,-1);
52WeekLow:=LowestSince(1,1YearAgo=1 AND Ref(1YearAgo,-1)=0,L);
New52WeekLow:=L<Ref(52WeekLow,-1);
New52WeekLow
----------
-colC-
{ma >= trading days forces Explorer to use enough data for this scan}
Mov(C,260,S)
----------------
-Filter-
colA OR colB
====================================================
- END -
====================================================
ruagoodp wrote:
Hi kaj,
You would have to subscribe to his monthly newsletter which
incidentally is well worth the money.
Cheers
Norman
--- In Metastockusers@xxxxxxxxxxxxxxx, kaj444s <kaj444s@xxxx> wrote:
What scan(s) are you guys talking about? I can't find any emails
from
Roy about a 52 week high scan or an advance decline scan.
Thanks,
kaj
Roy Larsen wrote:
Hi Norman
Is it possible to set up this scan in the same vein as your advance
decline scan exploration?
Cheers
Norman
Yes. Almost any exploration can could be acumulated in the same
way. I've got one for Trade Equity
that gives equity and number-of-trade totals without the report
needing to be copied to Excel for
summary.
Kind regards
Roy Larsen
www.metastocktips.co.nz
Free formulas and MS links
Yahoo! Groups Links
Yahoo! Groups Links
Yahoo! Groups Links
<*> To visit your group on the web, go to:
http://groups.yahoo.com/group/Metastockusers/
<*> To unsubscribe from this group, send an email to:
Metastockusers-unsubscribe@xxxxxxxxxxxxxxx
<*> Your use of Yahoo! Groups is subject to:
http://docs.yahoo.com/info/terms/
Yahoo! Groups Links
|
|