[EquisMetaStock Group] Re: What is Ergodic?

["Jose" <josesilva22@xxxxxxxxx>]

Darren, try this version of the Ergodic Oscillator:

=======
Ergodic
=======
---8<---------------------------

{ William Blau's Ergodic indicator }
{ With thanks to William Schamp,
   ProfLogic@xxxxxxxxxxxxx }
{ Incorporating auto overbought/sold levels }
{ http://users.bigpond.com/prominex/pegasus.htm }

{ User inputs }
choose:=Input("Version:  [1]Basic,  [2]Proflogic's Ensign",1,2,2);
message:=Input("Proflogic's Ensign orig: EMApds 28, SmoothPds 84",0,0,
0);
pds1:=Input("EMA periods",1,252,21);
pds2:=Input("Smoothing periods",1,252,10);
pds3:=Input("Signal periods",1,252,10);
plot:=Input("[1]Ergodic,  [2]Histogram",1,2,1);

{ Ergodic }
x:=Mov(Mov(H-L,pds1,E),pds2,E);
x:=If(x>0,x,.000001);
ergo1:=(Mov(Mov(C-O,pds1,E),pds2,E)/x)*100;

{ Proflogic's Ensign Ergodic version:
   EMA periods = 28, Smoothing periods = 84 }
ergo2:=
 Mov(Mov(Mov(C-Ref(C,-1),pds1,W),pds2,W),pds1,W)
/Mov(Mov(Mov(Abs(C-Ref(C,-1)),pds1,W),pds2,W),
 pds1,W)*100;

{ Selected Ergodic version }
ergodic:=If(choose=1,ergo1,ergo2);

{ Ergodic signal & histogram }
signal:=Mov(ergodic,pds3,E);
hist:=ergodic-signal;
ergoPlot:=If(plot=1,ergodic,hist);

{ Average (zero-line) }
ergoPlotAvg:=
 Cum(ergoPlot)/Cum(IsDefined(ergoPlot));

{ Auto overbought/sold boundaries }
Pk:=Ref(ergoPlot,-1)=HHV(ergoPlot,3)
 AND Ref(ergoPlot,-1)>ergoPlotAvg;
PkVal:=ValueWhen(1,Pk,Ref(ergoPlot,-1));
Obought:=Cum(PkVal)/Cum(IsDefined(PkVal));
Tr:=Ref(ergoPlot,-1)=LLV(ergoPlot,3)
 AND Ref(ergoPlot,-1)<ergoPlotAvg;
TrVal:=ValueWhen(1,Tr,Ref(ergoPlot,-1));
Osold:=Cum(TrVal)/Cum(IsDefined(TrVal)); 

{ Plot in own window }
If(plot=1,signal,ergoPlotAvg);
Obought;Osold;ergoPlot

---8<---------------------------


jose '-)



--- In equismetastock@xxxxxxxxxxxxxxx, Darren Liew <darrenliew@xxxx> 
wrote:
> 
> Hi Metastock Guru,
> 
> Have anybody come across an indicator called
> "Ergodic"?
> 
> Is it available in Metastock Charting Software?
> 
> 
> 
> Rgds,
> Darren Liew






------------------------ Yahoo! Groups Sponsor --------------------~--> 
Make a clean sweep of pop-up ads. Yahoo! Companion Toolbar.
Now with Pop-Up Blocker. Get it for free!
http://us.click.yahoo.com/L5YrjA/eSIIAA/yQLSAA/BefplB/TM
--------------------------------------------------------------------~-> 

 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/equismetastock/

<*> To unsubscribe from this group, send an email to:
    equismetastock-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/