[Metastockusers] ATR - True & Reverse

["Jose" <josesilva22@xxxxxxxxx>]

Whilst coding the True/Reverse ATR indicator below, I've noticed that 
MetaStock Pro v8.01 smooths ATR's erroneously.  The MS exponential 
smoothing is based on periods*2-1.

For example, MetaStock's ATR(10) is the same as Mov(ATR(1),19,E).
If I've missed something here, I'd appreciate it if someone would 
please correct me.

====================
ATR - True & Reverse
====================
---8<---------------

{ True ATR and Reverse-ATR v1.0 }
{ ©Copyright 2004 Jose Silva }
{ josesilva22@xxxxxxxxx }

{ Reverse True Range is the the *smallest*
  of the following for each period:
  * The distance from today's High
    to today's Low;
  * The distance from yesterday's Close
    to today's High;
  * The distance from yesterday's Close
    to today's Low.}

plot:=Input("[1]true ATR, [2]MS-compatible ATR, [3]Reverse ATR",1,3,1)
;
pds:=Input("ATR/RATR periods",1,252,10);
pdsN:=Input("normalizing periods (1=none)",
 1,2520,1);

x1:=ValueWhen(2,1,C);
ATR1:=Max(H-L,Max(Abs(x1-H),Abs(x1-L)));
ATRtrue:=Mov(ATR1,pds,E);
ATRmeta:=Mov(ATR1,pds*2-1,E);
rATR:=
 Mov(Min(H-L,Min(Abs(x1-H),Abs(x1-L))),pds,E);
TR:=If(plot=1,ATRtrue,If(plot=2,ATRmeta,rATR));
ATRnorm:=(TR-LLV(TR,pdsN))
 /(HHV(TR,pdsN)-LLV(TR,pdsN)+.000001)*100;
ATRplot:=If(pdsN<2,TR,ATRnorm);

ATRplot

---8<---------------


jose '-)




 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
     http://groups.yahoo.com/group/Metastockusers/

<*> To unsubscribe from this group, send an email to:
     Metastockusers-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
     http://docs.yahoo.com/info/terms/