Re: [Metastockusers] Gann HiLo

["Bill Hebert" <billhebert@xxxxxxxxxxx>]

Thanks Henry,

I have not done allot with Gann but this is a good way to 
have indicators that get me started,...


----- Original Message ----- 
From: "Henry Z Kaczmarczyk" <henry1224@xxxxxxxxx>
To: <Metastockusers@xxxxxxxxxxxxxxx>
Sent: Saturday, February 07, 2004 8:14 AM
Subject: [Metastockusers] Gann HiLo


> this is the Gann Hi LO indicator
> 
> HLd:=If(C>Ref(Mov(H,3,S),-1),1,
> If(C<Ref(Mov(L,3,S),-1),-1,0));
> HLv:=ValueWhen(1,HLd<>0,HLd);
> HiLo:=If(HLv=-1,Mov(H,3,S),Mov(L,3,S));
> HiLo;
> 
> This is the Gann Swing Indicator
> 
> {Market swing is defined as:
> Up = 2 higher highs,
> Down = 2 lower highs.}
> Us:=BarsSince((H > Ref(H,-1)) AND (Ref(H,-1) > 
> Ref(H,-2)));
> Ds:=BarsSince((L < Ref(L,-1)) AND (Ref(L,-1) < 
> Ref(L,-2)));
> Sd1:=If(Us=0,
> {then}If(Ref(L,-1)<>LowestSince(1,Ds=0,L),
> {then}1,
> {else}0),
> {else}If(Ds=0,
> {then}If(Ref(H,-1)<>
> HighestSince(1,Us=0,H),
> {then}-1,
> {else}0),
> {else}0));
> Sd2:=If(Sd1=1,
> {then} If(Ref(BarsSince(Sd1=1),-1) >
> Ref(BarsSince(Sd1=-1),-1),
> {then}1,
> {else}0),
> {else} If(Sd1=-1,
> {then}If(Ref(BarsSince(Sd1=1),-1) <
> Ref(BarsSince(Sd1=-1),-1),
> {then}-1,
> {else}0),
> {else}0));
> TD1:=ValueWhen(1,Sd2<>0,Sd2);
> Td1;
> 
> This is the Gann Trend Indicatot
> 
> {Swing Direction}
> Sd:= FmlVar("GANN-Swing","TD1") ;
> {Swing Change High}
> Sch:=If(Sd=1 AND Ref(sd,-1)=-1,
> {then}1,
> {else}0);
> {Swing Change Low}
> Scl:=If(Sd=-1 AND Ref(Sd,-1)=1,
> {then}1,
> {else}0);
> {Peak Value}
> Pv:=If(Scl=1,
> {then}HighestSince(1,Sch=1,H),
> {else}0);
> {Trough Value}
> Tv:=If(Sch=1,
> {then}LowestSince(1,Scl=1,L),
> {else}0);
> {Trend Direction}
> Td:=If(H>ValueWhen(1,Pv>0,Pv),
> {then}1,
> {else}If(L<ValueWhen(1,Tv>0,Tv),
> {then}-1,
> {else}0));
> {UpTrend=1 DownTrend =-1}
> Tdv:=ValueWhen(1,Td<>0,Td);
> Tdv;
> 
> 
> 
>  
> Yahoo! Groups Links
> 
> 
> 
>  
> 



 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
     http://groups.yahoo.com/group/Metastockusers/

<*> To unsubscribe from this group, send an email to:
     Metastockusers-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
     http://docs.yahoo.com/info/terms/