|
PureBytes Links
Trading Reference Links
|
See Jose's response to a similar request on another forum. It's called an Equity Curve. Set display
option to 8 to see when the trade is active and when it is not. You can verify the equity curve
value through any trade with some very simple maths. Start by setting the entry and exit commissions
to zero (change default value for 'Cn' from 3434 to 0000) and a long equity curve is as easy to
calculate as it gets. If you compare this equity curve against the MetaStock System Tester curve
just remember that MS is compounding equity and this code is not. If you trade that way then there
is a compounding version of Trade Equity that you can use instead.
This code has been called a trade simulator. Use it how you will. There is an entire family of
indicators and explorations available. I will attempt to answer any questions you might have.
Roy
Hi, I am trying to put my "concept" of trading into the system trader
but it seem that without actually knowing what is going on, I'm not
really convinced that it is actually working the way I want it. Is
there a facility in Metastock that, like Excel, shows you the step by
step working of the formulea? Ok, thanks.
----- Original Message -----
From: "Jose" <josesilva22@xxxxxxxxx>
To: <Metastockusers@xxxxxxxxxxxxxxx>
Sent: Thursday, January 29, 2004 5:05 AM
Subject: [Metastockusers] Re: Equity line
>
> From
> http://users.bigpond.com/prominex/pegasus.htm#roy
>
> ---8<---------------------------
>
> {Trade Equity LE}
> {V4.2a, © 2003 Roy Larsen}
> {rlarsen@xxxxxxxxxxxxxx}
> B:=Input("Entry 1=O 2=C 3=H 4=L 5=Stop",1,5,2);
> Z:=Input("Exit 1=O 2=C 3=H 4=L 5=Stop" ,1,5,2);
> Nd:=Input("Entry Delay",0,3,0);
> Xd:=Input("Exit Delay", 0,3,0);
> Cn:=Input("Entry / Exit Costs",0,9999,3434);
> En:=Input("Display Options 0-12",0,12,0);
> Cp:=10000; {* trade capital, 0 = points only}
> F:=1; {* position size}
> N:=RSI(C,14)<30; {MS entry}
> Ns:=0;;
> X:=RSI(C,14)>70; {MS exit}
> Xs:=0;
> {* end user area *}
> F:=If(F=0,1,F);
> Ns:=(B=5)*Ns;
> Cx:=Cn-100*Int(Cn/100);
> Cn:=Int(Cn/100);
> M:=If(Ns>0,Ns,If(B=1,O,If(B=3,H,If(B=4,L,C))));
> N:=N AND Alert(N=0,2);
> X:=If(Z<5,X AND Alert(X=0,2),0);
> F:=ValueWhen(1,(N+Ns)>0 OR Cum((N+Ns)>-1),F);
> N:=If(Nd=0,N,Alert(N,Nd+1) AND Alert(N,Nd)=0);
> N:=If(B=5 AND Ns>0,1,If(B<5,N,0));
> Y:=If(Xs>0,Min(H,Max(L,Xs)),
> If(Z=1,O,If(Z=3,H,If(Z=4,L,C))));
> X:=If(Xd=0,X,Alert(X,Xd+1) AND Alert(X,Xd)=0);
> X:=If(Xs>0,1,X);
> Y:=If(Z<5 AND B=5 AND X=0,C,Y);
> Y:=If(Xs>0 AND N AND X,Xs,Y);
> I:=Cum((N+X)>-1)=1;
> Y:=If(I OR (Alert(N AND X,2))=0,Y,ValueWhen(2,1,Y));
> N:=If(I>-1,N,0);
> Tr:=BarsSince(I+N>0)<(BarsSince(I+X>0)+(Cum(N)=1 AND Cum(I+X)=1));
> Tr:=If(N+X>1 AND (Alert(Tr,2) OR (Nd+Xd<1 AND
> B<>2 AND Z>1 AND (Max(B,Z)>4 OR B<>Z))),1,Tr);
> Nd:=En;
> En:=Tr+Alert(Tr=0,2)=2 OR I;
> Ex:=Tr=0 AND Alert(Tr,2);
> M:=If(I AND N=0,C,M);
> Lb:=Alert(Tr,2) AND LastValue(Cum(1))=Cum(1);
> A:=ValueWhen(1,En,If((B=5)+N+X=3,M,Max(O,M)));
> A:=If(B<5,ValueWhen(1,En,M),A);
> F:=ValueWhen(1,En,If(F<1,Cp*F,If(F>1, (A*F)+Cn,Cp)));
> En:=Tr+(Alert(Tr=0,2)+I>0)=2;
> Z:=Nd;
> N:=If(Ex+Lb>0,If(Cp=0,Y-A-Cn-Cx,(F-Cn)*(Y/A)-F-If(Ex,Cx,0)),0);
> B:=If(Alert(Tr,2),1+BarsSince(En OR I),0);
> Xs:=If(Alert(Tr,2),If(Cp=0,Y-A,(F-Cn)*(Y/A)-F-If(Ex,Cx,0)),0);
> Nd:=LowestSince(1,I,Xs);
> Ns:=HighestSince(1,I,Xs);
> X:=Cum((Ex+Lb>0 AND N>0)*B);
> Xd:=Cum((Ex+Lb>0 AND N<=0)*B);
> M:=Cum(N)+Cp+(Tr AND Lb=0)*
> If(Cp=0,Y-A-Cn,(F-Cn)*(Y/A)-F);{M}
> {options
> 0 total $ equity
> 1 total % equity
> 2 $ equity/trade
> 3 % equity/trade
> 4 winning trade $
> 5 losing trade $
> 6 winning trade #
> 7 losing trade #
> 8 trade in progress
> 9 bars/trade
> 10 bars/all trades
> 11 MFE
> 12 MAE}
> If(Z=0,M,
> If(Z=1,100*(M-Cp)/Cp,
> If(Z=2,N+M-Cp-Cum(N),
> If(Z=3,100*(N+M-Cp-Cum(N))/Cp,
> If(Z=4,Cum((N>0)*N),
> If(Z=5,Cum((N<0)*N),
> If(Z=6,Cum(N>0),
> If(Z=7,Cum(Ex+Lb>0 AND N<=0),
> If(Z=8,Tr,
> If(Z=9,BarsSince(I OR Alert(Tr,2)=0)*Alert(Tr,2),
> If(Z=10,Cum(Alert(Tr,2)),
> If(Z=11,Ns,Nd))))))))))));
>
> ---8<---------------------------
>
> Ask Roy about his Short Equity indicators.
>
> jose '-)
>
>
> > --- In Metastockusers@xxxxxxxxxxxxxxx, "Curroleo" <curroleo@xxxx>
> > wrote:
> > > Hi everyone,
> > >
> > > I got a question and I´d would appreciate suggestions.
> > > I wonder if it´s possible to plot an equity line as an indicator
> > with the parameters of a trading system.
> > >
> > > For example, How to do it with a system such as,
> > > Enter long: rsi(c,14)<30
> > > Close long:rsi(c,14)>70
> > > Enter short: rsi(c,14)>70
> > > Close short:rsi(c,14)<30
> > >
> > > Thank you in advance.
>
>
>
>
>
> Yahoo! Groups Links
>
> To visit your group on the web, go to:
> http://groups.yahoo.com/group/Metastockusers/
>
> To unsubscribe from this group, send an email to:
> Metastockusers-unsubscribe@xxxxxxxxxxxxxxx
>
> Your use of Yahoo! Groups is subject to:
> http://docs.yahoo.com/info/terms/
>
>
>
>
>
Yahoo! Groups Links
To visit your group on the web, go to:
http://groups.yahoo.com/group/equismetastock/
To unsubscribe from this group, send an email to:
equismetastock-unsubscribe@xxxxxxxxxxxxxxx
Your use of Yahoo! Groups is subject to:
http://docs.yahoo.com/info/terms/
|