|
PureBytes Links
Trading Reference Links
|
------------------------------------------------------------------------
You cannot reply to this message via email because you have chosen not
to disclose your email address to the group.
To reply: http://groups.yahoo.com/group/equismetastock/post?act=reply&messageNum=5865
------------------------------------------------------------------------
Alex
> Is there away to search via Explorers for both Weekly
> and Daily uptrends in MACD Histogram?
Yes there is. This is why I have put some time and effort into developing a
number of weekly indicators for daily charts. The following 'Weekly MACD'
could be tested in one column of an exploration and the standard MACD tested
in another. This indicator is provided with a signal line that can be used
or commented out as required.
Because this indicator requires a PREV for each EMA (12, 26, signal line) it
will run more slowly than your current exploration, and for reasonable
accuracy with each (weekly) EMA your exploration should use at least 250
periods.
> Currently I am doing it via one time in Daily, and
> another via Weekly, and then see if those two results
> match for a given stock. Very tedious! It would be
> great if there is a way to do it all in one run.
If you have problems setting this up for an exploration I have some ideas
that will help but take a look first.
Roy
{Weekly MACD} {for daily charts}
Hs:=Input("0=Line, or 1=Histogram",0,1,0);
{use histogram for chart display only}
P1:=Input("Weeks for Short EMA",1,99,12);
P2:=Input("Weeks for Long EMA",1,99,26);
P3:=Input("Weeks for Signal Line",1,99,9);
P1:=2/(P1+1); P2:=2/(P2+1); P3:=2/(P3+1);
Q:=Input("1=Update at Friday bar, Dynamic Current Week",0,0,0);
Q:=Input("2=Update at Friday bar, 3=Update at Monday bar",1,3,2);
{1=dynamic current week, MS compatible}
{2=update @ end of week except when no Friday}
{3=update @ start of new week}
Lb:=LastValue(Cum(1)-0)=Cum(1);
W1:=DayOfWeek()=5;
W2:=DayOfWeek()<=Ref(DayOfWeek(),-1);
We:=If(W1,1,If(Alert(W1,2)=0 AND W2,2,0));
Cl:=ValueWhen(1,We>0,If(We=1,C,Ref(C,-1)));
Ma:=If(Cum(We>0)=1,Cl,ValueWhen(1,We>0,PREV)*(1-P1)+Cl*P1);
Ma:=If(Q=1 AND We=0 AND Lb,ValueWhen(1,We>0,Ma) *(1-P1)+C*P1,Ma);
Ma:=If(DayOfWeek()=5 AND Q=3,Ref(Ma,-1),Ma);
Mb:=If(Cum(We>0)=1,Cl,ValueWhen(1,We>0,PREV)*(1-P2)+Cl*P2);
Mb:=If(Q=1 AND We=0 AND Lb,ValueWhen(1,We>0,Mb) *(1-P2)+C*P2,Mb);
Mb:=If(DayOfWeek()=5 AND Q=3,Ref(Mb,-1),Mb);
Md:=(Ma-Mb);
Sg:=If(Cum(We>0)=1,Md,ValueWhen(1,We>0,PREV)*(1-P3)+Md*P3);
Sg:=If(Q=1 AND We=0 AND Lb,ValueWhen(1,We>0,Sg) *(1-P3)+Md*P3,Sg);
Sg:=If(DayOfWeek()=5 AND Q=3,Ref(Sg,-1),Sg);
Md:=If(Hs=0,Md,If(Md<>Ref(Md,-1),Md,0));
Md; Sg;
To unsubscribe from this group, send an email to:
equismetastock-unsubscribe@xxxxxxxxxxxxxxx
Your use of Yahoo! Groups is subject to http://docs.yahoo.com/info/terms/
|