Re: Dallas System by Keith Fitschen

[Philip <pschmi02@xxxxxxxxxxx>]

Glen, Andrew, Wooglin . . .  I sent the whole shebang to Dave privately by
mistake instead of to the whole list.

Here goes again, and great that you're willing to give it a shot! The EL
codes follows. There are no restrictions on it that I know of, after all,
it was handed out free at a public gathering. Nor are there any
restrictions listed on the diskette. Of course, attribution is always the
decent way to go. I have also attached the material, both as a word .doc
and an EL file.

I understand that the system refers to a separate TradeStation function
called "Abb.stddev". I don't know how to handle that, but I've added an EL
explanation of the function which I received from a cyber-friend. The
"Abb.stddev"code follows "Dallas" below.

I hope your efforts are rewarded with a few trading ideas.

Much obliged,
Philip

==============================================

{
Type : System
Name : Dallas
Notes: Keith Fitschen

}

Inputs: Length(50),   Lookback(22) , NumStd(1.5);

Vars  : SetStop(0), Sigma(0), Avg(0), Stopp(0), LongStop(0), ShortStop(0);

Sigma = Abb.stddev  (Close, Length);
Avg = (Sigma+Sigma[1]+Sigma[2])/3;

if MarketPosition = 1 and SetStop=1 then begin
   SetStop=0;
   Stopp=EntryPrice - NumStd * Sigma[1];
end;

if MarketPosition = -1 and SetStop=1 then begin
   SetStop=0;
   Stopp=EntryPrice + NumStd * Sigma[1];
end;

if MarketPosition = 0 and LongStop = 0 and ShortStop=0 and Sigma > Avg and
Sigma > Sigma[22] and
Close > Close[22] and Close < Close[1]  then begin
  Setstop=1;
  Buy  ("long.dallas") at market ;
end ;

if MarketPosition = 0 and LongStop = 0 and ShortStop = 0 and Sigma > Avg
and Sigma > Sigma[22] and
Close < Close[22] and Close > Close[1]  then begin
   Setstop=1;
  Sell  ("short.dallas") at market ;
end ;

if MarketPosition = 1 and Sigma < Sigma[22] then
   ExitLong  ("dallas.normLout") at market ;

if MarketPosition = -1 and Sigma < Sigma[22] then
   ExitShort  ("dallas.normSout") at market ;

if MarketPosition = 0 and (LongStop = 1 or ShortStop = 1) and Sigma <
Sigma[22] then begin
   LongStop=0;
    ShortStop=0;
End;

if MarketPosition = 1 and Close < Stopp then begin
    LongStop = 1;
   ExitLong  ("dallas.StopLout") at market ;
end;

if MarketPosition = -1 and Close > Stopp then begin
    ShortStop = 1;
   ExitShort  ("dallas.StopSout") at market ;
end;
=================================================
"Abb.stddev"

{ *******************************************************************

 Study  : Standard Deviation (Series)

 Provided By : Keith fitschen

********************************************************************}
inputs : Price(NumericSeries),Length(NumericSimple);
vars    : SumSqr(0),Avg(0),Counter(0);

if Length <> 0
then begin
 Avg = Average(Price,Length);
 SumSqr = 0;
 for counter = 0 to Length - 1
 begin
  SumSqr = SumSqr + (Price[counter]-Avg) * (Price[counter]-Avg);
 end;
Print (Date, SumSqr:3:4) ;
   if (SumSqr > 0.0001)
     then abb.StdDev = SquareRoot (SumSqr / (Length- 1))
     else abb.StdDev = abb.StdDev[1] ;
end
else
 abb.StdDev = 0 ;

Philip wrote:

> Greetings,
>
> Several weeks ago at a presentation in New York, Keith Fitschen
> discussed a profitable, volatility-based system of his called "Dallas."
> Fitschen is no slouch (understatement of the day) when it comes to
> developing systems.
>
> Unfortunately "Dallas" is written in EL. Does anyone have the metastock
> code for this system? . . . or is anyone willing/able to translate the
> EL code into MS if I supply it?
>
> Best regards,
> Philip Schmitz

Attachment: Description: "Dallas_ELA.doc"

Attachment: Description: "Dallas.ela"