Re: Dynamic Multiple Time Frames

["Adam Hefner" <VonHef@xxxxxxxxxx>]

Here is an update to one of the formula's to compensate for
missing trade periods (Holiday's).

name: FT-FBP

  {Fibonacci Trader - Fixed Balance Point}
  {NOTE: under Color/Style options, change
         plot to last "style" option}

 {Fixed Balance Point Calculation}
FBC:=If(DayOfWeek()=1 AND Ref(DayOfWeek(),-1)
     <5,
     {then}(HighestSince(2,DayOfWeek()=1,H)+
          LowestSince(1,DayOfWeek()=1,L)+
          CLOSE)/3,
     {else}If(DayOfWeek()=5,
         {then}(HighestSince(1,DayOfWeek()=1,H)+
          LowestSince(1,DayOfWeek()=1,L)+
          CLOSE)/3,
         {else}0));
 {Fixed Balance Point Plot}
FBP:=ValueWhen(1,FBC>0,FBC);
FBP

  Best wishes,
      Adam Hefner.
 VonHef@xxxxxxxxxx

-------------------------------------
-----Original Message-----
From: Chuck Wemlinger <yeti@xxxxxxxxxxxxxxx>
To: metastock@xxxxxxxxxxxxx <metastock@xxxxxxxxxxxxx>
Date: Tuesday, January 05, 1999 1:00 AM
Subject: Re: Dynamic Multiple Time Frames


>Adam,
>
>Gee, thanks.  I was just working on this and along comes your e-mail.  I'll
>check it out tomorrow.
>
>Chuck
>
>-----Original Message-----
>From: Adam Hefner <VonHef@xxxxxxxxxx>
>To: MetaStock <metastock@xxxxxxxxxxxxx>
>Date: Monday, January 04, 1999 9:56 PM
>Subject: Dynamic Multiple Time Frames
>
>
>>In the 1999 Bonus Issue of TASC the article by Robert Krausz named
>>"Dynamic Multiple Time Frames", he describes a method of using
>>different time frames to determine trends. In the section he calls
>>"Fibonacci Trader" he reveals how to calculate different indicators
>>he calls "Balance Points" I have coded my interpretation of his
indicators,
>>please examine.....and let me know if the logic is correct.
>>
>>name: FT-S&R
>>  {Fibonacci Trader- Support & Resistance}
>>  {NOTE: under Color/Style options, change
>>         plot to last "style" option}
>>
>> {Weekly Price Range Calculation}
>>WRC:=If(DayOfWeek()>=5,
>>     {then}HighestSince(1,DayOfWeek()=1,H)-
>>          LowestSince(1,DayOfWeek()=1,L),
>>     {else}0);
>>WRP:=ValueWhen(1,WRC>0,WRC);
>> {Resistance Range}
>>RR1:= FmlVar("FT-FBP","FBP")+(WRP*.5);
>>RR2:= FmlVar("FT-FBP","FBP")+(WRP*.618);
>> {Support Range}
>>SR1:= FmlVar("FT-FBP","FBP")-(WRP*.5);
>>SR2:= FmlVar("FT-FBP","FBP")-(WRP*.618);
>> {Plot Ranges}
>>RR1;
>>RR2;
>>SR1;
>>SR2;
>>
>>name: FT-FBP
>>  {Fibonacci Trader - Fixed Balance Point}
>>  {NOTE: under Color/Style options, change
>>                plot to last "style" option}
>>
>> {Fixed Balance Point Calculation}
>>FBC:=If(DayOfWeek()=5,
>>    {then}(HighestSince(1,DayOfWeek()=1,H)+
>>          LowestSince(1,DayOfWeek()=1,L)+
>>          CLOSE)/3,
>>    {else}0);
>> {Fixed Balance Point Plot}
>>FBP:=ValueWhen(1,FBC>0,FBC);
>>FBP
>>
>>name: FT-DBP
>>  {Fibonacci Trader - Dynamic Balance Point}
>>  {Dynamic Balance Point Calculation}
>>dt:=DayOfWeek();
>>DBC:=(HighestSince(5,DayOfWeek()=dt,H)+
>>     LowestSince(5,DayOfWeek()=dt,L)+CLOSE)/3;
>>DBC;
>>
>>name: FT-FBPS
>>  {Fibonacci Trader-Fixed Balance Point Step}
>>FPS:=(ValueWhen(1,FmlVar("FT-FBP","FBC")>0,
>>     FmlVar("FT-FBP","FBC")) +
>>     ValueWhen(2,FmlVar("FT-FBP","FBC")>0,
>>     FmlVar("FT-FBP","FBC")) +
>>     ValueWhen(3,FmlVar("FT-FBP","FBC")>0,
>>     FmlVar("FT-FBP","FBC")) +
>>     ValueWhen(4,FmlVar("FT-FBP","FBC")>0,
>>     FmlVar("FT-FBP","FBC")) +
>>     ValueWhen(5,FmlVar("FT-FBP","FBC")>0,
>>     FmlVar("FT-FBP","FBC")))/5;
>>FPS
>>
>>name: FT-DBPS
>>  {Fibonacci Trader-Dynamic Balance Point Step}
>>DPS:=(ValueWhen(1,FmlVar("FT-DBP","DBC"),
>>     FmlVar("FT-DBP","DBC"))+
>>     ValueWhen(5,FmlVar("FT-DBP","DBC"),
>>     FmlVar("FT-DBP","DBC"))+
>>     ValueWhen(10,FmlVar("FT-DBP","DBC"),
>>     FmlVar("FT-DBP","DBC"))+
>>     ValueWhen(15,FmlVar("FT-DBP","DBC"),
>>     FmlVar("FT-DBP","DBC"))+
>>     ValueWhen(20,FmlVar("FT-DBP","DBC"),
>>     FmlVar("FT-DBP","DBC")))/5;
>>DPS;
>>
>>  Best wishes,
>>      Adam Hefner.
>> VonHef@xxxxxxxxxx
>>
>>-------------------------------------
>>
>>
>
>