|
PureBytes Links
Trading Reference Links
|
CMA,
I'll copy an old post below.
Jim
--------------------------------------
The Rsquared, S/C,MFI test is based on linear regression.
RSquared is a function that measures how strong a data array of given
length is trending. A return of one correlates to a very strong trend
in either direction. A return of zero correlates to no trend. I'm
using it to tell me when there is no trend over the last 21 days, or
that rsquared(C,21) is less than 0.15. Now that we have no trend, we
would expect one to start in the next 5 to 13 days. If one does start
we want to determine the direction and get in early. Therefore
Rsquared is used as a trigger, using it as an ALERT function. With
the ALERT given, if all the rest of the conditions are met any time
within a 13 day period, the buy signal will be generated. I'm then
using S/C and MFI to determine trend start and direction.
S/C is nothing more than the normalized 34 day LinRegSlope of the
close. I normalize it by dividing it by the close so charts are more
directly comparable. I also multiply by 10000 just to get numbers
between 0 and a few hundred. Finally I apply Tema smoothing to get a
smoother plot. The theory is that if S/C is rising then a uptrend is
in progress. If S/C is falling a down trend is in progress. I check
this by making sure that tema(S/C) is larger than an optimized value
(opt1) and is rising. I use the function HHV(X,5) = HHV(X,13) to
check. This is just a quick way to determine if the most reason
values of X have been rising. If the condition is met, then S/C is
rising. Similarly if it met the condition LLV(X,5) = LLV(C,13) it
would be falling.
I double check the result by also making sure that MFI is also
rising. When all conditions are met within 13 days of the alert, we
get a buy signal. The converse is true for a sell signal. Since the
market is biased upwards, I add two additional checks for the short -
MFI less then 0 and the 55 day variable moving average falling. I
close the positions when the trend has stopped. For the long position
I check that the Tema(MFI) is below 0, the Tema(S/C) is below opt 1
and a 55 day exp moving average is falling. Short positions tend to
move faster, so I only look the 144 day moving aver to begin rising to
close that position. The complete test follows:
ENTER LONG:
Alert(RSquared(C,21) < 0.15,13) AND
Tema(10000*LinRegSlope(C,34)/C,34) > opt1 AND
HHV(Tema(10000*LinRegSlope(C,34)/C,34),5) =
HHV(Tema(10000*LinRegSlope(C,34)/C,34),13) AND
HHV(Tema(MFI(55),55),5) = HHV(Tema(MFI(55),55),13)
CLOSE LONG:
Tema(MFI(55),55) - 50 < 0 AND
Tema(10000*LinRegSlope(C,34)/C,34) < opt1 AND
LLV(Tema(10000*LinRegSlope(C,34)/C,34),5) =
LLV(Tema(10000*LinRegSlope(C,34)/C,34),13) AND
LLV(Tema(MFI(55),55),5) = LLV(Tema(MFI(55),55),13)
ENTER SHORT
Alert(RSquared(C,21) < 0.15,13) AND
Tema(10000*LinRegSlope(C,34)/C,34) < opt2 AND
LLV(Tema(10000*LinRegSlope(C,34)/C,34),5) =
LLV(Tema(10000*LinRegSlope(C,34)/C,34),13) AND
LLV(Tema(MFI(55),55),5) = LLV(Tema(MFI(55),55),13) AND
Tema(MFI(55),55) - 50 < 0 AND
LLV(Mov(C,55,VAR),5) = LLV(Mov(C,55,VAR),13)
CLOSE SHORT
HHV(Mov(C,55,VAR),5) = HHV(Mov(C,55,VAR),13) AND
Tema(MFI(55),55) - 50 > 0
OPTIMIZATION:
OPT1: Min=-34 Max=-8 Step=13
OPT2: Min=-55 Max=-21 Step=34
-----Original Message-----
From: amc amc <cma6@xxxxxxxxx>
To: metastock@xxxxxxxxxxxxx <metastock@xxxxxxxxxxxxx>
Date: Wednesday, July 15, 1998 11:09 AM
Subject: Tema
>
>To Jim Greening:Don't know if you have covered this, but can you
>describe Tema S/C and Tema MFI (money flow index?), howconstructed
>and how interpreted. Thanks, CMA
>
>
>
>_________________________________________________________
>DO YOU YAHOO!?
>Get your free @yahoo.com address at http://mail.yahoo.com
>
|