|
PureBytes Links
Trading Reference Links
|
>From: Rob Cloutier <cloutier@xxxxxxxxxxx>
>To: "'metastock@xxxxxxxxxxxxx'" <metastock@xxxxxxxxxxxxx>
>I just bought Coopers book "Hit and Run Trading - The Short-Term Stock
>Trader's Bible". Set me back a c-note. Hope it is worth it. Comes
>highly recommended. I ordered from Borders, though I know it can also
be
>ordered from Amazon. They both have to order from publisher. Will
take
>4-6 weeks. Has anyone written MS6.5 experts for these things yet?
>Rob Cloutier
>Mullica Hill, NJ
>cloutier@xxxxxxxxxxx
>
{1234 buy}
(ADX(14) > 30 AND
PDI(14) > MDI(14)) AND
{3 LOWER LOWS IN A ROW}
((L < Ref(L,-1) AND
Ref(L,-1) < Ref(L,-2) AND
Ref(L,-2) < Ref(L,-3)) OR
{2 LOWER LOWS IN A ROW AND AN INSIDE DAY}
(Ref(L,-2) < Ref(L,-3) AND
Ref(L,-1) < Ref(L,-2) AND
H <= Ref(H,-1) AND L >= Ref(L,-1))
OR
{AN INSIDE DAY AND 2 LOWER LOWS}
(Ref((H <= Ref(H,-1) AND (L >= Ref(L,-1))),-2) AND
Ref(L,-1) < Ref(L,-2) AND
L < Ref(L,-1)))
{1234 sell}
(ADX(14) > 30 AND
PDI(14) < MDI(14)) AND
{3 HIGHER HIGHS IN A ROW}
((H > Ref(H,-1) AND
Ref(H,-1) > Ref(H,-2) AND
Ref(H,-2) > Ref(H,-3)) OR
{2 HIGHER HIGHS IN A ROW AND AN INSIDE DAY}
(Ref(H,-2) > Ref(H,-3) AND
Ref(H,-1) > Ref(H,-2) AND
H <= Ref(H,-1) AND L >= Ref(L,-1)) OR
{AN INSIDE DAY AND 2 HIGHER HIGHS}
(Ref((H <= Ref(H,-1) AND (L >= Ref(L,-1))),-2) AND
Ref(H,-1) > Ref(H,-2) AND
H > Ref(H,-1)))
180 b
C > Mov(C,10,S) AND
C > Mov(C,50,S) AND
Ref(C,-1) <= (Ref(L,-1)+(Ref(H-L,-1)*.25)) AND
C >= L + ((H-L) * .75)
180 s
C < Mov(C,10,S) AND
C < Mov(C,50,S) AND
Ref(C,-1) >= (Ref(L,-1)+(Ref(H-L,-1)*.75)) AND
C <= L + ((H-L) * .25)
boomer b
ADX(14) > 30 AND PDI(14) > MDI(14) AND
H <= Ref(H,-1) AND Ref(H,-1) <= Ref(H,-2) AND
L >= Ref(L,-1) AND Ref(L,-1) >= Ref(L,-2)
boomer s
ADX(14) > 30 AND PDI(14) < MDI(14) AND
H <= Ref(H,-1) AND Ref(H,-1) <= Ref(H,-2) AND
L >= Ref(L,-1) AND Ref(L,-1) >= Ref(L,-2)
expansion b
C > Ref(HHV(C,42),-1) AND
H-L >= Ref(HHV((H-L),9),-1)
expansion s
C < Ref(LLV(C,42),-1) AND
(H-L) >= Ref(HHV((H-L),9),-1)
pivot b
H-L > Ref(HHV((H-L),9),-1) AND
((L <= Mov(C,50,S)) OR Ref(L,-1) <= Ref(Mov(C,50,S),-1))
AND
C > Mov(C,50,S)
pivot s
H-L > Ref(HHV((H-L),9),-1) AND
((H >= Mov(C,50,S)) OR Ref(H,-1) >= Ref(Mov(C,50,S),-1))
AND
C < Mov(C,50,S)
gilligan b
GapDown() AND
O < Ref(LLV(L,41),-1) AND
C >= ((H+L)/2) AND C >= O
gilligan s
GapUp() AND
O > Ref(HHV(H,41),-1) AND
C <= ((H+L)/2) AND C <= O
lizard b
O >= L + ((H-L) * .75) AND
C >= L + ((H-L) * .75) AND
L < Ref(LLV(L,9),-1)
lizard s
O <= L + ((H-L) * .25) AND
C <= L + ((H-L) * .25) AND
H > Ref(HHV(H,9),-1)
slingshot b
(Ref(H > Ref(HHV(H,42),-1),-1) AND
L <= (Ref(L,-1) - .125)) OR (Ref(H > Ref(HHV(H,42),-1),-2) AND
Ref(L<=(Ref(L,-2) - .125),-1))
slingshot s
2ML:=LLV(L,42);
(Ref(L < Ref(2ml,-1),-1) AND
H >= (Ref(H,-1) + .125)) OR (Ref(L < Ref(2ml, -1),-2) AND Ref(H >=
(Ref(H,-2) + .125),-1))
whoops b
C<Mov(C,10,S) AND
C<Mov(C,50,S) AND
O<Ref(C,-1)-0.25
whoops s
C>Mov(C,10,S) AND
C>Mov(C,50,S) AND
O>Ref(C,-1)+0.25
______________________________________________________
Get Your Private, Free Email at http://www.hotmail.com
|