[amibroker] Re: Referencing composite values in an Exploration

["Mike" <sfclimbers@xxxxxxxxx>]

After running your initial scan, you could run a separate exploration 
to output the values calculated during the scan.

First, if there's no particular reason for specifically storing your 
composite values separately in "H", "L", "O", then change your code 
to store the value in all fields (i.e. "X"), else always in the same 
field (e.g. "C"). It does not appear that you are using any more than 
a single field for any of these composites. Always using the same 
field makes the exploration easier.

e.g. change:

AddToComposite( Advanced, "~I " + Industry + " U" + " Adv", "H" );

to:

AddToComposite( Advanced, "~I " + Industry + " U" + " Adv", "X" );

Then run an exploration like the following, with a filter set to 
Market 253 (i.e. composites):

Buy = 0;

Prefix = StrLeft(Name(), 2);
Suffix = StrRight(Name(), 6);

switch (Prefix) {
	case "~I":
	case "~S":
	case "~M":
		PrefixMatch = True;
		break;

	default:
		PrefixMatch = False;
}

switch (Suffix) {
	case " U Adv":
	case " U Dec":
	case " U Unc":
		SuffixMatch = True;
		break;

	default:
		SuffixMatch = False;
}

Filter = (PrefixMatch && SuffixMatch);
AddColumn(Close, "Count");

Mike

--- In amibroker@xxxxxxxxxxxxxxx, "tiger_energy" <kuantau@xxx> wrote:
>
> Hello,
> 
> Can anyone suggest a way to reference this code in an exploration
> using the addcolumn function? I'd like to be able
> to reference the sector and industry data to see the advances,
> declines and unchanged values for export from exploration to excel.
> 
> thanks
> Anthony
> 
> 
> Buy = 0; // required for scan
> YestClose = Ref( Close, -1 );
> Advanced = Close > YestClose;
> Declined = Close < YestClose;
> Unchanged = Close == YestClose;
> Industry = GetBaseIndex();
> Sector = StrLeft( Industry, 4 ) + "0";
> Market = MarketID( 1 );
> AddToComposite( Advanced, "~I " + Industry + " U" + " Adv", "H" );
> AddToComposite( Declined, "~I " + Industry + " U" + " Dec", "L" );
> AddToComposite( Unchanged, "~I " + Industry + " U" + " Unc", "O" );
> AddToComposite( Advanced, "~S " + Sector + " U" + " Adv", "H" );
> AddToComposite( Declined, "~S " + Sector + " U" + " Dec", "L" );
> AddToComposite( Unchanged, "~S " + Sector + " U" + " Unc", "O" );
> AddToComposite( Advanced, "~M " + Market + " U" + " Adv", "H" );
> AddToComposite( Declined, "~M " + Market + " U" + " Dec", "L" );
> AddToComposite( Unchanged, "~M " + Market + " U" + " Unc", "O" );
>



------------------------------------

**** IMPORTANT ****
This group is for the discussion between users only.
This is *NOT* technical support channel.

*********************
TO GET TECHNICAL SUPPORT from AmiBroker please send an e-mail directly to 
SUPPORT {at} amibroker.com
*********************

For NEW RELEASE ANNOUNCEMENTS and other news always check DEVLOG:
http://www.amibroker.com/devlog/

For other support material please check also:
http://www.amibroker.com/support.html

*********************************
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/amibroker/

<*> Your email settings:
    Individual Email | Traditional

<*> To change settings online go to:
    http://groups.yahoo.com/group/amibroker/join
    (Yahoo! ID required)

<*> To change settings via email:
    mailto:amibroker-digest@xxxxxxxxxxxxxxx 
    mailto:amibroker-fullfeatured@xxxxxxxxxxxxxxx

<*> To unsubscribe from this group, send an email to:
    amibroker-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/