Re: [amibroker] Color code, AmiBroker Email List Archive

----- Original Message -----

From: Anthony Faragasso

To: amibroker@xxxxxxxxxxxxxxx

Sent: Saturday, April 09, 2005 11:53 AM

Subject: Re: [amibroker] Color code

here is the formula.

//Pattern Recognition graph

//with shading

/*TRENDLINES BREAKOUT*/

x = Cum(1);

per = Param("Percent",3,1,5,1);

s1=L;

s11=H;

pS = TroughBars( s1, per, 1 ) == 0;

endt= LastValue(ValueWhen( pS, x, 1 ));

startt=LastValue(ValueWhen( pS, x, 2 ));

endS = LastValue(ValueWhen( pS, s1, 1 ) );

startS = LastValue( ValueWhen( pS, s1, 2 ));

dtS =endt-startt;

aS = (endS-startS)/dtS;

bS = endS;

trendlineS = aS * ( x -endt ) + bS;

pR = PeakBars( s11, per, 1 ) == 0;

endt1= LastValue(ValueWhen( pR, x, 1 ));

startt1=LastValue(ValueWhen( pR, x, 2 ));

endR = LastValue(ValueWhen( pR, s11, 1 ) );

startR = LastValue( ValueWhen( pR, s11, 2 ));

DTR=ENDT1-STARTT1;

aR = (endR-startR)/dtR;

bR = endR;

trendlineR = aR * ( x -endt1 ) + bR;

BEGIN=Min(STARTT,STARTT1);

TRS = IIf(x>BEGIN-10,trendlineS,-1e10);

TRR = IIf(x>BEGIN-10,trendlineR,-1e10);

Condcolor=(Cross(C,trendlineR) AND X>ENDT1) OR (Cross(trendlineS,C) AND

X>ENDT);

BarColor=IIf(Condcolor,7,1);

Plot(C,"Close",BarColor,styleCandle);

Plot(TRS,"Support",colorYellow,styleLine);

Plot(TRR,"Resist",colorYellow,styleLine);

/////////////////////////////////////

// Shading //

////////////////////////////////////

fill=Param("style",2,1,2,1);

>IIf(fill==1,styleHistogram,IIf(fill==2,styleArea,Null));

x=IIf(trs > trr,trr,trs);

Plot(x,"",colorLightGrey,style);

Plot(trr,"",colorPink,style);

////////////////////////////////////////////

// Pattern Recognition in title bar //

///////////////////////////////////////////

Lowline=Ends-starts;

Highline=endr-startr;

Wedge=IIf(Highline <0 AND Lowline > 0,1,0);

DecendingTriangle=IIf(Highline < 0 AND Lowline==0,1,0);

AscendingTriangle=IIf(Highline==0 AND Lowline > 0,1,0);

DownChannel=IIf(Highline<0 AND Lowline<0,1,0);

UpChannel=IIf(Highline>0 AND Lowline>0,1,0);

BroadeningWedge=IIf(Highline > 0 AND Lowline < 0,1,0);

///////////////////////////////////

// Bullish or Bearish breakout //

//////////////////////////////////

BullishBreakout=Cross(C,trendlineR);

BearishBreakout=Cross(trendlineS,C);

Title=Name()+ WriteIf(wedge==1," Wedge","")+WriteIf(DecendingTriangle==1," Decending Triangle","")+WriteIf(AscendingTriangle==1,"Ascending Triangle","")/*+WriteVal(Lowline)*/+WriteIf(DownChannel==1," Downward Sloping Channel","")+WriteIf(UpChannel==1," Upward Sloping Channel","")+WriteIf(broadeningWedge==1," Broadening Wedge","")+"\n"+EncodeColor(colorGreen)+WriteIf(bullishbreakout,"Bullish Breakout",EncodeColor(colorRed)+WriteIf(bearishbreakout,"Bearish Breakout",""))/*+WriteVal(highline)*/;

/////////////////////////////////////

// Automatic Analysis //

////////////////////////////////////

Filter=AscendingTriangle OR DecendingTriangle OR Wedge OR DownChannel OR UpChannel OR BroadeningWedge OR Bullishbreakout OR bearishbreakout;

AddTextColumn(WriteIf(bullishbreakout,"bullish Breakout",""),"BullBreak");

AddTextColumn(WriteIf(bearishBreakout,"Bearish Breakout",""),"BearBreak");

AddTextColumn(WriteIf(ascendingtriangle,"Ascending Triangle",WriteIf(decendingtriangle,"Decending Triangle",WriteIf(Wedge,"Wedge",WriteIf(DownChannel,"Down Channel",WriteIf(UpChannel,"Up Channel",WriteIf(BroadeningWedge,"Broadening Wedge","")))))),"Pattern");

----- Original Message -----

From: wavemechanic

To: amibroker@xxxxxxxxxxxxxxx

Sent: Friday, April 08, 2005 11:20 PM

Subject: Re: [amibroker] Color code

Yes, how did you do that?

----- Original Message -----

From: Anthony Faragasso

To: amibroker@xxxxxxxxxxxxxxx

Sent: Friday, April 08, 2005 10:30 PM

Subject: Re: [amibroker] Color code

Bill,

Do you mean something like the attached image ?

Anthony

----- Original Message -----

From: wavemechanic

To: AmiBroker, User

Sent: Friday, April 08, 2005 8:06 PM

Subject: [amibroker] Color code

Has anyone successfully developed (or tried to develop) a generalized code for coloring an area defined by 3 or more lines? For example, a triangle created with the zig-zag charting tool and a baseline. Or a rectangle defined by two dates and two price levels. Not unlike the "fill with color" option in Microsoft's Paint. And along the same lines, is it possible to change the transparency of such coloring so that the underlying price bars, etc. are still visible?

Sounds like "mission impossible" with the AFL tools at our disposal but thought I would ask and maybe get "lucky."

Bill

Please note that this group is for discussion between users only. To get support from AmiBroker please send an e-mail directly to SUPPORT {at} amibroker.com For other support material please check also: http://www.amibroker.com/support.html

No virus found in this incoming message.
Checked by AVG Anti-Virus.
Version: 7.0.308 / Virus Database: 266.9.5 - Release Date: 4/7/2005

No virus found in this outgoing message.
Checked by AVG Anti-Virus.
Version: 7.0.308 / Virus Database: 266.9.5 - Release Date: 4/7/2005